My Blog

ArduinoのADCの基準電圧は次の３つの指定が可能である

• DEFAULT: 電源電圧(5V)が基準電圧（デフォルト）
• INTERNAL: 内蔵基準電圧を使用（ATmega168と328Pでは1.1V）
• EXTERNAL: AREFピンに供給される電圧(0V～5V)を基準電圧とする（電源電圧を超えてはならないとの事）

外部供給にしないなら電源電圧と内蔵基準電圧１．１Ｖの２つ利用可能である

そこで精度の良い方を利用したいのでどのくらい精度が変わるのか確認してみることにする

基準電源

確認にあたって基準電源が必要で以前実験したシャントレギュレータを利用しようかなっと・・・

ところがブレッドボードで実験したまま放置だったため直ぐに使用できるようになってない

先ずは今後も使うことがあるだろうってことで基板に組むことにした

既に使い方は判っているのでサクッと基板に載せた

元電源は５～９Ｖ位のＡＣアダプタを使う（電池でも可能）

目の前にちょうど空いたＤＡＩＳＯの糸付ようじのケースがあったので使うことする

こんな感じになる

多少でかいのは空きの部分に電池ボックスを実装できるようにするため

出力端子は未実装なのでしばらく（ずーとかも）は使う時に蓋を開ける

実はＬＥＤが非常に明るすぎた・・・眩しいので少し寝かせた（写真は寝かせてない時に撮ったもの）

電源電圧（５Ｖ）を基準で測定

（注）電流値の表示は無視して良い

２．４６５Ｖ：かなりずれがある

４．０９６Ｖ：同様にずれあり

内蔵基準電圧（１．１Ｖ）で測定

２．４６５Ｖ：大きい方へずれている

４．０９６Ｖ：同様に大きい方へずれている

結論

• 電源電圧基準と内蔵基準電圧どちらとも補正が必要である
• 秒毎にサンプリングしていて（写真では判らないが）内蔵基準電圧だと電圧の変動が多い（つまり安定しない）
• 電源電圧基準の方が良さそうである

(追加）

良く考えてみたら，今回の評価は条件もあいまいで単に内蔵基準電圧でやってみたって感じなので，近日中（となるかどうかは判らないが）に改めて評価し直すことにする

内蔵基準電圧（１．１Ｖ）を評価すべき事項としては

• １．１Ｖまでの分解能が１／１０２４の約１ｍＶであるか？
• 分圧する場合の最大電圧の適正値は？

で，（精度と安定性が高いのであれば）内蔵基準電圧だけでADCが使えるってことを確かめるって事だ

消費中の電流と起電力の電圧を表示するために表示部を追加しようとしている

まずはブレッドボードで確認（左が５Ω負荷，右が０．５Ω負荷）

電流と電圧以外にボタンを押して覚えさせ表示されておく初期電圧と充電池用に元切りやブザーを鳴らす終了電圧を設定表示も行いたいと考えている

今回，電圧換算で詳細な電圧を得るため電圧に合わせてレンジ切換えしてみようと考えて，Ａ１～Ａ３を以下のように接続してみた

    P1-------------------------+       -> A1
    R1=45kΩ                   | 5.00V
    P2----------------+->      |       -> A2
    R2=15kΩ          | 12.50V |
    P3-------+->      |        |       -> A3
    R3=15kΩ | 25.00V |        |
    Grd------+--------+--------+       -> Grd

プログラムは，

//電圧読込：電圧によりレンジ切換え
//    Ａ１：電圧（０～５Ｖ）
//    Ａ２：電圧（０～１２．５Ｖ）
//    Ａ３：電圧（０～２５Ｖ）
//
static int readVolt() {
    int e, val = (-1);
    if((e = analogRead(PIN_VOLTM05)) < 1023) {
        val = map(e, 0, 1023, 0, 4999);
    } else if((e = analogRead(PIN_VOLTM13)) < 1023) {
        val = map(e, 0, 1023, 0, 12499);
    } else if((e = analogRead(PIN_VOLTM25)) < 1023) {
        val = map(e, 0, 1023, 0, 24999);
    }
    return(val);
}

だが，上記のようなことはできないようで，例えばＡ１がオーバーフロー状態だとＡ２，Ａ３に影響する

具体的にはＡ１がオーバーフロー状態だと全体の抵抗値に影響を与えＡ２，Ｐ３が期待通りの分圧された電圧にならない

アナログポートをＯＦＦできれば可能な感じだが調査はまたにすることにしてＡ１，Ａ２を外しＡ３でのみ取得にした（またＭａｘ．２０Ｖに変更）

秋月電子のＩ２Ｃ接続小型キャラクタＬＣＤ（AQM1602XA）を利用するための表示用ライブラリを作ることにした

電子負荷の消費電流および電源電圧の表示部を作製しようとしたところ今後も良く使いそう（毎日でないので使い方を忘れてしまうから）なのでライブラリにしておこうと考えた訳である

ライブラリ化する方法と注意点

• ライブラリはＩＤＥの環境設定で指定したフォルダに新規のライブラリフォルダを作ってファイルを置く
• 必要ファイルは，ＸＸＸ．ｈとＸＸＸ．ｃｐｐとなる（その他は無くても問題なし，．ｃではダメだった）
• ＸＸＸは同じでなくてはならない
• 新規のライブラリフォルダ名はＸＸＸでなくても良い

 

AQM1602LCD.h

#define _AQM1602_H_
#if ARDUINO >= 100
 #include "Arduino.h"
#else
 #include "WProgram.h"
#endif

#define LCD_ADDR 0x3E

void LCD_clearScreen(void);
void LCD_setLocate(int col, int row);
void LCD_putChar(byte c);
void LCD_putString(byte *str);
void LCD_init3();
void LCD_init5();
#endif /* AQM1602LIB_H */

AQM1602LCD.cpp

// LCD_init3        - ＬＣＤの初期化（３．３Ｖ）
// LCD_init5        - ＬＣＤの初期化（５Ｖ）
//
// LCD_clearScreen  - ＬＣＤモジュールの画面をクリア
// LCD_setLocate    - ＬＣＤモジュール画面内のカーソル位置を移動
// LCD_putChar      - ＬＣＤにデータを１バイト出力
// LCD_putString    - ＬＣＤに文字列データを出力
//

#include <Wire.h>
#include "AQM1602LCD.h"

// ＬＣＤにコマンドを送信
//
static void LCD_writeCommand(byte command) {
    Wire.beginTransmission(LCD_ADDR);    // スタートコンディション
    Wire.write(0x00);                    // control byte の送信(コマンドを指定)
    Wire.write(command);                // command byte の送信
    Wire.endTransmission();                // ストップコンディション
    delay(10);
}

// ＬＣＤにデータを送信
//
static void LCD_writeData(byte data) {
    Wire.beginTransmission(LCD_ADDR);    // スタートコンディション
    Wire.write(0x40);                    // control byte の送信(データを指定)
    Wire.write(data);                    // data byte の送信
    Wire.endTransmission();                // ストップコンディション
    delay(1);
}

// ＬＣＤの初期化
//
static void LCD_init(int volt) {
    Wire.begin();

    delay(100);
    LCD_writeCommand(0x38); delay(20);        // Function set
    LCD_writeCommand(0x39); delay(20);        // IS=1
    LCD_writeCommand(0x14); delay(20);        // Internal OSC frequency

    if(volt == 3) {
        // 3.3V
        LCD_writeCommand(0x73); delay(20);    // Contrast set
        LCD_writeCommand(0x56); delay(20);    // POWER/ICON/Contrast control
    } else /* if(volt == 5) */ {
        // 5V
        LCD_writeCommand(0x7A); delay(20);    // Contrast set
        LCD_writeCommand(0x52); delay(20);    // POWER/ICON/Contrast control
    }
    LCD_writeCommand(0x6C); delay(20);        // Follower control
    LCD_writeCommand(0x38); delay(20);        // Function set
    LCD_writeCommand(0x01); delay(20);        // Clear Display
    LCD_writeCommand(0x0C); delay(20);        // Display ON
    LCD_writeCommand(0x06); delay(20);        // Entry Mode
}

// ＬＣＤの初期化（３．３Ｖ）
//
void LCD_init3() {
    LCD_init(3);
}

// ＬＣＤの初期化（５Ｖ）
//
void LCD_init5() {
    LCD_init(5);
}

// ＬＣＤモジュールの画面をクリア
//
void LCD_clearScreen(void) {
    LCD_writeCommand(0x01);                // Clear Display
}

// ＬＣＤモジュール画面内のカーソル位置を移動
//    col : 横(列)方向のカーソル位置(0-15)
//    row : 縦(行)方向のカーソル位置(0-1)
//
void LCD_setLocate(int col, int row) {
    static int row_offsets[] = { 0x00, 0x40 } ;
    // Set DDRAM Adddress : 00H-0FH,40H-4FH
    LCD_writeCommand(0x80 | (col + row_offsets[row]));
}

// ＬＣＤにデータを１バイト出力
//      c :  出力する文字データを指定
//
void LCD_putChar(byte c) {
    LCD_writeData(c);
}

// ＬＣＤに文字列データを出力
//    str :  出力する文字列
//
void LCD_putString(byte *str) {
    while(*str) LCD_writeData(*str++);
}

ライブラリインタフェースはコメントのとおり

ヘッダーファイルの

#include "Arduino.h"

を，忘れがちなので忘れないようにする事

（追加：2017.01.22）

Ｃ＋＋に書き換えた

注意点

• コンストラクタで電圧の指定とかやってみたが上手く動作しないので保留（現状はsetup()を呼び出す仕様）
• 割込み禁止で使うとハングアップするようだ
• Ｃ版も使用しているので名称を変更

AQMI2CLCD.h

//秋月電子通商 Ｉ２Ｃ接続小型キャラクタＬＣＤモジュール
//    AQM0802A-RN-GBW（８ｘ２行）
//    AQM0802A-FLW-GBW（８ｘ２行，バックライト付）
//    AQM1602XA-RN-GBW（１６ｘ２行）
//
//Sitronix ST7032 CONTROLED
//    電源電圧：2.7～5.5V
//    インターフェース：I2C
//    Ｉ２Ｃアドレス：0x3E
//    Ｉ２Ｃスピード：　最大400kHz
//    使用可能温度：-30～+85℃
//
#ifndef _AQMI2CLCD_H_
#define _AQMI2CLCD_H_
#if ARDUINO >= 100
 #include <Arduino.h>
#else
 #include <WProgram.h>
#endif

#define AQMI2CLCD_ADDR 0x3E

class AQMI2CLCD {
    public:
//        AQMI2CLCD();
        void setup();
        void setup(int);
        void clearScreen(void);
        void setLocate(int, int);
        void putChar(char);
        void putString(char *);
        void putString(int);
};

#endif /* AQMI2CLCD_H */

AQMI2CLCD.cpp

//秋月電子通商 Ｉ２Ｃ接続小型キャラクタＬＣＤモジュール
//
// コンストラクタ
// void AQMI2CLCD()
//
// void setup
// void setup(int)
//        3        - ＬＣＤの初期化（３．３Ｖ）
//        5        - ＬＣＤの初期化（５Ｖ）
// void clearScreen    - ＬＣＤモジュールの画面をクリア
// void setLocate    - ＬＣＤモジュール画面内のカーソル位置を移動
// void putChar        - ＬＣＤにデータを１バイト出力
// void putString    - ＬＣＤに文字列データを出力
//
#include <AQMI2CLCD.h>
#include <Wire.h>

//AQMI2CLCD::AQMI2CLCD() {}

// ＬＣＤにコマンドを送信
//
static void LCD_writeCommand(byte command) {
    Wire.beginTransmission(AQMI2CLCD_ADDR);    // スタートコンディション
    Wire.write(0x00);                        // control byte の送信(コマンドを指定)
    Wire.write(command);                    // command byte の送信
    Wire.endTransmission();                    // ストップコンディション
    delay(10);
}

// ＬＣＤにデータを送信
//
static void LCD_writeData(byte data) {
    Wire.beginTransmission(AQMI2CLCD_ADDR);    // スタートコンディション
    Wire.write(0x40);                        // control byte の送信(データを指定)
    Wire.write(data);                        // data byte の送信
    Wire.endTransmission();                    // ストップコンディション
    delay(1);
}

// ＬＣＤの初期化
//
static void LCD_init(int volt) {
    Wire.begin();

    delay(100);
    LCD_writeCommand(0x38); delay(20);        // Function set
    LCD_writeCommand(0x39); delay(20);        // IS=1
    LCD_writeCommand(0x14); delay(20);        // Internal OSC frequency

    if(volt == 3) {
        // 3.3V
        LCD_writeCommand(0x73); delay(20);    // Contrast set
        LCD_writeCommand(0x56); delay(20);    // POWER/ICON/Contrast control
    } else /* if(volt == 5) */ {
        // 5V
        LCD_writeCommand(0x7A); delay(20);    // Contrast set
        LCD_writeCommand(0x52); delay(20);    // POWER/ICON/Contrast control
    }
    LCD_writeCommand(0x6C); delay(20);        // Follower control
    LCD_writeCommand(0x38); delay(20);        // Function set
    LCD_writeCommand(0x01); delay(20);        // Clear Display
    LCD_writeCommand(0x0C); delay(20);        // Display ON
    LCD_writeCommand(0x06); delay(20);        // Entry Mode
}

// ＬＣＤセットアップ
//
void AQMI2CLCD::setup() {
    LCD_init(5);
}
void AQMI2CLCD::setup(int volt) {
    LCD_init(volt);
}

// ＬＣＤモジュールの画面をクリア
//
void AQMI2CLCD::clearScreen(void) {
    LCD_writeCommand(0x01);                // Clear Display
}

// ＬＣＤモジュール画面内のカーソル位置を移動
//    col : 横(列)方向のカーソル位置(0-15)
//    row : 縦(行)方向のカーソル位置(0-1)
//
void AQMI2CLCD::setLocate(int col, int row) {
    static int row_offsets[] = { 0x00, 0x40 } ;
    // Set DDRAM Adddress : 00H-0FH,40H-4FH
    LCD_writeCommand(0x80 | (col + row_offsets[row]));
}

// ＬＣＤにデータを１バイト出力
//      c :  出力する文字データを指定
//
void AQMI2CLCD::putChar(char c) {
    LCD_writeData(c);
}

// ＬＣＤに文字列データを出力
//    str :  出力する文字列
//
void AQMI2CLCD::putString(char *str) {
    while(*str) LCD_writeData(*str++);
}
void AQMI2CLCD::putString(int n) {
    char bf[16];
    sprintf(bf, "%d\0", n);
    char *str = bf;
    while(*str) LCD_writeData(*str++);
}

予告なく改良

しばらく何もできなくて，ふと思い出したのがニッケル水素電池の事

カメラやビデオカメラなど専用バッテリーは思い出して定期的に充電しているが，エネループを使い始めてエネループ以外のニッケル水素電池の充電をすっかり忘れるようになってしまった

で，すっかり忘れて放置していた以下の充電池を確認したら電圧が低下していて危ない事になっていた（すべて２個ごとあった）

①秋月で購入したニッケル水素電池パック（３セル：３．６Ｖ）

②コードレス電話の子機用バッテリ（２セル：２．４Ｖ）

③１００￥ショップのライトから取り出したバッテリ（１セル：１．２Ｖ）

充電には３．６Ｖ用の充電用ＡＣアダプタを利用

①はブレッドボードに簡単な回路を展開して充電

充電完了はテスターで電圧確認した

②③は電圧を下げるべきだったが，不良になるのを覚悟のうえ急速充電できるか，そのままやってみた

結果的には放置期間が長すぎた②と③のバッテリ１個が使用不可となる（それぞれ残り１個は問題なし）

定期的に充電するためそれぞれに適応する充電器を作製しておいたほうが良さそう考えてみようってことで検討

• 良く使うものではないので，まずは単純かつ安上がりで良しとする
• セル１～３までを対象とし，既に簡易９Ｖ用充電器があり９Ｖ（セル７）も含まれるものにしたい
• 将来の改造を見据えインテリジェントとしＡＶＲを使う（拙者はソフト屋ですし）
• いつものことで完了期限なし

充電完了を電圧を判断する方法とすれば出来そうに思える